There is no good way of handling this. You can use charindex to identify
word boundaries but this doesn't work well for FreeText type searches. I
posted a tsql solution in the other newsgroups you also posted to.

Hi Maya
We did a similar thing but with the added bonus of keyword
highlighting. In ASP you pass your text column plus an array of the
search words to the function and it returns a google-like keyword
highlighting with surrounding text.
Marc

Function search_HighlightKeywords(description, arrWords)

  Dim Summary
  Summary = ""

  ' Ensure spaces at start and end for our regex
  description = " " & description & " "

  Dim word
  For Each word In arrWords
     Dim RegEx
     Set RegEx = New RegExp
     RegEx.Global = True
     RegEx.IgnoreCase = True
     word = Replace(word, """", "")
     RegEx.Pattern = "[\s\-].{1,30}(" & word & ")[^a-z].{1,30}[\s\-]"
     Dim Matches
     Set Matches = RegEx.Execute(description)
     Dim Match
     For Each Match In Matches
        If Len(Summary) < 300 Then
           Summary = Summary & "..." & search_HighlightTextWord(match,
word)
        End If
     Next
  Next

  ' Ensure all words highlighted
  For Each word In arrWords
     Summary = search_HighlightTextWord(Summary, word)
  Next

  search_HighlightKeywords = Summary

End Function

Function search_HighlightTextWord(text, word)
  Dim t1
  t1 = InStr(1, text, word, 1)
  If t1>1 Then
     search_HighlightTextWord = Left(text, t1-1) & "<b>" & _
     Mid(text, t1, Len(word)) & "</b>" & Mid(text, t1 + Len(word))
  Else
     search_HighlightTextWord = text
  End If
End Function