SELECT permissions on all user tables and views can be assigned by adding
users to the db_datareader fixed database role.  There is no such role for
executing procs but you can assign such permissions by creating your own
role and using a script like the one below to grant permissions on all
existing stored procedures:

SET NOCOUNT ON

DECLARE @GrantStatement nvarchar(4000)

DECLARE GrantStatements CURSOR
LOCAL FAST_FORWARD READ_ONLY FOR
SELECT
   N'GRANT EXECUTE ON ' +
   QUOTENAME(ROUTINE_SCHEMA) +
   N'.' +
   QUOTENAME(ROUTINE_NAME) +
   N' TO SpExecuteRole'
FROM INFORMATION_SCHEMA.ROUTINES
WHERE
   OBJECTPROPERTY(
       OBJECT_ID(QUOTENAME(ROUTINE_SCHEMA) +
           N'.' +
           QUOTENAME(ROUTINE_NAME)),
       'IsMSShipped') = 0 AND
   OBJECTPROPERTY(
       OBJECT_ID(QUOTENAME(ROUTINE_SCHEMA) +
           N'.' +
           QUOTENAME(ROUTINE_NAME)),
       'IsProcedure') = 1
OPEN GrantStatements
WHILE 1 = 1
BEGIN
   FETCH NEXT FROM GrantStatements
       INTO @GrantStatement
   IF @@FETCH_STATUS = -1 BREAK
   BEGIN
      RAISERROR (@GrantStatement, 0, 1) WITH NOWAIT
      EXECUTE sp_ExecuteSQL @GrantStatement
   END
END
CLOSE GrantStatements
DEALLOCATE GrantStatements